میکروکنترلر 8051 - آزمایش میکروکنترلر 8051
آزمایش اول : اتصال یک LED به میکروکنترلر
خوب اگه وسایل و قطعات لیست مذکور را تهیه کردید ، نرم افزار Keil را دانلود و نصب کرده و به راحتی میتونید یک پروژه ی جدید ایجاد کنید ، پروگرامر شرح داده شده در بالا را ساخته و تست کردید و منبع تغذیه ی 5+ولت را هم ساختید ، میریم سراغ اولین و در واقع ساده ترین آزمایش که اتصال یک LED به میکروکنترلر و روشن و خاموش کردن آن است . در این آزمایش ما دو هدف را دنبال میکنیم : 1_ اتصال صحیح یک LED به میکرو و 2_ ایجاد یک تأخیر یک ثانیه ای نسبتاً دقیق با استفاده از تایمر صفر . قبل از اینکه به سراغ آزمایشهای بعدی بریم ، باید این تذکر را بدم که من توی این وبلاگ قصد آموزش برنامه نویسی اسمبلی را ندارم و فرض را بر این میگذارم که شما با دستورات اسمبلی و نحوه ی کاربرد اونها کاملاً آشنا هستید .
از اونجائیکه پورتهای میکروکنترلرهای سری 8051 فقط در حالت خروجی صفر جریاندهی خوبی دارند و جریان دهی پورتها در حالت خروجی یک ، برای روشن کردن یک LED کافی نیست ، در اینجا پایه ی کاتد LED را به میکرو وصل کرده و پایه ی آند LED را هم با یک مقاومت 470 اهم به 5+ولت وصل می کنیم . لازمه به این نکته اشاره کنم که LED هایی مورد استفاده من از نوع مرغوب هستند که حتی با یک مقاومت 7/4 کیلو اهم هم روشن می شوند و فکر کنم در اکثر شهرها هم از این نوع LED پیدا میشه .
برتامه ی میکرو را هم در زیر مشاهده می کنید . در این برنامه از تایمر صفر در مود یک استفاده شده که با توجه به مقداردهی اولیه پس از 62500 میکرو ثانیه سر ریز می کند و پس از هر بار سر ریز محتوای رجیستر R2 با دستور Djnz یک واحد کم می شود . با توجه به مقداردهی اولیه این رجیستر که عدد 16 هست ، سرانجام پس از 16 بار تکرار حلقه مذکور زمانی برابر 62500*16 میکرو ثانیه یا 1000000 میکروثانیه سپری خواهد شد که همان یک ثانیه می باشد . پس از گذشت زمان یک ثانیه وضعیت پایه ی P0.0 که LED به آن متصل است معکوس می شود و پس از مقدار دهی دوباره ی R2 برنامه مجدداً وارد حلقه ی تاخیر می شود .
Org 0H
Sjmp Main
Main: Mov Tmod,#01H
Mov r2,#16
Initialize: Mov Th0,#0BH
Mov Tl0,#0DBH
Setb Tr0
Jnb Tf0,$
Clr Tr0
Clr Tf0
Djnz r2,Initialize
Cpl P0.0
Mov r2,#16
Sjmp Initialize
End
==================
========================
========================
==================
آزمایش دوم : اتصال سون سگمنت به میکروکنترلر
با امید به اینکه اولین آزمایش را با موفقیت انجام دادید ، میریم سراغ آزمایش دوم که اتصال یک سون سگمنت به میکرو کنترلر و ساختن یک شمارنده هست . البته سون سگمنتی که من در لیست قطعات مورد نیاز آورده بودم از نوع 4 تایی مالتی پلکس شده هست و لازم میدونم تا قبل از اینکه به سراغ مطالب بعدی بریم مختصری در مورد تکنیک مالتی پلکس برای روشن کردن چندین سون سگمنت روی یک مسیر a ،b ،c ،d ،e ،f و g مشترک توضیح بدم .
برای اتصال مستقیم و بدون واسطه ی چندین سون سگمت به میکروکنترلر (بدون استفاده از تراشه های مبدل BCD به سون سگمنت مانند 7448 ) که سون سگمنتها به همون دلیلی که در مورد اتصال LED به میکروکنترلر گفتم حتماً بایستی از نوع آند مشترک باشند دو روش وجود دارد . روش اول اینه که هر سون سگمنت را به یکی از پورتهای میکرو وصل کنید . البته مقاومتهای محدود کننده ی جریان را هم که بین پایه های a تا g سون سگمنت و پورتهای میکرو قرار میگیرند نباید فراموش کنید . در صورت عدم قرار دادن این مقاومتها که مقدار آنها بسته به کیفیت سون سگمنت مورد استفاده بین 470اهم تا 5/1 کیلو اهم میتونه باشه ، هم سون سگمنتها و هم پورتهای میکرو آسیب میبینه . آند سون سگمنتها هم مستقیماً به 5+ ولت تغذیه وصل میشه . استفاده از این روش وقتی که تعداد سون سگمنتها بیشتر از یکی باشه و بخواهیم قطعات دیگه ای مثل صفحه کلید و یا مبدل آنالوگ به دیجیتال(ADC) و یا بالعکس (مبدل دیجیتال به آنالوگ یا DAC) را هم به میکرو متصل کنیم ، غیر ممکنه . زیرا میکروکنترلر 4 تا پورت بیشتر نداره و نمیشه همزمان چند تا سون سگمنت ، یک صفحه کلید و یک ADC را به میکرو وصل کرد . البته وقتی هر یک از سون سگمنتها را به یکی از پورتها وصل کنیم برنامه نویسی خیلی آسون میشه ولی در مقایسه با محدودیتی که از نظر سخت افزار برای ما ایجاد میکنه اهمیتی نداره .
راهکار دوم در اتصال بدون واسطه ی چندین سون سگمنت به میکروکنترلر استفاده از روش مالتی پلکس هست که صرفه جویی قابل توجهی را در تعداد پایه های مورد استفاده از میکروکنترلر به همراه داره . در این روش ابتدا پایه های مشابه سون سگمنتها به هم و سپس این پایه ها از طریق مقاومتهای محدود کننده ی جریان که مقدار آنها در مقایسه با حالتی که از روش مالتی پلکس استفاده نکنیم کمتر هست ، به میکرو متصل میشه . مقدار مقاومتها در این حالت برای 4 عدد سون سگمنت مالتی پلکس شده از نوع مرغوب 470 اهم می باشد . هر یک از پایه های آند سون سگمنتها هم از طریق یک ترانزیستور منفی بعنوان یک بافر ولتاژ به منظور افزایش جریاندهی پایه های میکرو در حالت منطق خروجی یک به یکی از پایه های میکرو وصل میشه . جزئیات بیشتر در این مورد را میتونید با دانلود کردن نقشه ی شماتیک از اینجا مشاهده کنید .
همان طور که در نقشه نیز پیداست در این روش برای اتصال 4 عدد سون سگمنت به میکرو تنها به 12 تا از پایه های میکرو احتیاج داریم . یعنی یک پورت و 4 تا پایه از یک پورت دیگه . این روش را با حالتی که میخواستیم سون سگمنتها را بدون استفاده از تکنیک مالتی پلکس به میکرو وصل کنیم مقایسه کنید . در آنجا مجبور بودیم هر 4 پورت میکرو را به سون سگمنتها وصل کنیم و امکان اتصال قطعه ی دیگه ای به میکرو وجود نداشت .
البته امروزه دیگر لازم نیست که شما 4 عدد سون سگمنت آند مشترک تهیه کرده و آنها را بصورت مالتی پلکس به هم متصل کنید زیرا 4 عدد سون سگمنت مالتی پلکس شده به طور حاضری در دو نوع مشترک و کاتد مشترک تقریباً در همه ی مغازه های قطعات الکترونیک به فروش می رسد که از کیفیت خوبی هم برخوردار است . تنها موردی که شما می بایستی مد نظر داشته باشید آن است که نوع آند مشترک را بخرید . برای راحتی شما ترتیب پایه ها در این نوع از سون سگمنتها را هم از نمای روبرو در شکل زیر آوردم که خودتون هم به راحتی میتونید ترتیب پایه ها را تشخیص بدین .
B A2 A3 f a A4
A1 g c p d e
بعد از توضیحاتی در مورد نحوه ی اتصال سون سگمنت به میکروکنترلر به سراغ نحوه ی اتصال یک کلید فشاری که در بازار به تاچ سوئیچ معروف هست میریم . به طور کلی اتصال کلید های فشاری به میکرو کنترلر برای وارد کردن مقادیر ورودی و تنظیم پارامترهای یک مدار ساخته شده توسط میکروکنترلر بسیار مرسوم است . عمل این کلیدها بدین صورت است که با فشرن کلید اتصال بین پایه های آن برقرار شده و با قطع فشار بر روی کلید این اتصال نیز قطع می شود . این کلیدها در دو نوع 2 و 4 پایه در بازار موجود می باشند که در نوع 4 پایه ، 2 تا از پایه ها از داخل کلید به همدیگر متصل هستند و در مجموع همان 2 پایه را عرضه میکنند که شما بهتر است برای آسانی کار از همان نوع 2 پایه استفاده کنید . برای اتصال کلید های 2 پایه به میکرو یکی از پایه ها را به زمین تغذیه یا همان صفر ولت و پایه ی دیگر را هم به یکی از پایه های میکرو وصل کنید . بهتر است این پایه متعلق به یکی از پورتهای 1 ، 2 یا 3 باشد . زیرا این پورتها مقاومتهای بالا کش درونی دارند و به همین دلیل پایه ی مورد نظر که کلید به آن وصل است در حالت عادی که کلید فشرده نشده در سطح منطقی یک بوده و پس از آنکه کلید فشرده شود به سطح منطقی صفر می رود و از اینرو میتوان توسط کنترل وضعیت منطقی پایه ای که کلید به آن متصل است به فشرده شدن کلید پی برد . البته شما می توانید از پورت P0 نیز برای اتصال کلید استفاده کنید به شرطی که مقاومت بالا کش خارجی به کار ببرید یعنی توسط یک مقاومت حدوداً 7/4 کیلو اهمی از خارج پایه ای که کلید به آن متصل شده را به 5+ ولت وصل کنید . سخت افزارکامل این آزمایش را که یک شمارنده ی پالس هست میتونید از اینجا دانلود کنید .
پس از توضیحات مفصل در باره ی سخت افزار به سراغ نرم افزار میریم که مطمئن هستم خیلی منتظرش هستین . نرم افزار را در زیر مشاهده میکنید و توضیحات در مورد آنرا هم پس از آن آوردم .
Zero Equ 0C0H
One Equ 0F9H
Two Equ 0A4H
Three Equ 0B0H
Four Equ 99H
Five Equ 92H
six Equ 82H
Seven Equ 0F8H
Eight Equ 80H
Nine Equ 90H
Timer0_Preload Equ -5000
seven_segment Data P0
anode1 Bit P3.0
anode2 Bit P3.1
anode3 Bit P3.2
anode4 Bit P3.3
Pulse_Input Bit P1.0
Org 0H
Sjmp Main
;----------------
Org 0BH
Ajmp Multiplex
;-----------------
Main: Mov Tmod,#01H
Mov IE,#82H
Mov Tl0,#low Timer0_Preload
Mov Th0,#high Timer0_Preload
Mov Dptr,#Number_Codes
Mov r2,#0
Mov 30H,#0
Mov 31H,#0
Mov 32H,#0
Mov 33H,#0
Mov 34H,#0
Mov 35H,#zero
Mov 36H,#zero
Mov 37H,#zero
Mov 38H,#zero
Setb Tr0
Pulse_Check: Jb Pulse_Input,$
Acall Delay
Jb Pulse_Input, Pulse_Check
Mov a,30H
Add a,#1
Da a
Mov 30H,a
jnz Updade_Numbers
Mov a,31H
Add a,#1
Da a
Mov 31H,a
Mov 32h,31H
Acall Decode
Mov 37H,33H
Mov 38H,34H
Updade_Numbers: Mov 32h,30H
Acall Decode
Mov 35H,33H
Mov 36H,34H
Jnb Pulse_Input,$
Sjmp Pulse_Check
;-----------------
Decode: Mov a,32H
Anl a,#0Fh
Movc a,@a+dptr
Mov 33H,a
Mov a,32H
Swap a
Anl a,#0Fh
Movc a,@a+dptr
Mov 34H,a
Ret
;-----------------
Delay: Mov 39H,#50
Back: Mov 3AH,#100
Djnz 3AH,$
Djnz 39H,Back
ret
;-----------------------------
Multiplex: Clr Tr0
Mov Tl0,#low Timer0_Preload
Mov Th0,#high Timer0_Preload
Setb Tr0
Inc r2
Cjne r2,#1,Show_Dahgan
Clr anode4
Mov seven_segment,35H
Setb anode1
Reti
Show_Dahgan: Cjne r2,#2,Show_Sahgan
Clr anode1
Mov seven_segment,36H
Setb anode2
Reti
Show_Sahgan: Cjne r2,#3,Show_Yekanhezar
Clr anode2
Mov seven_segment,37H
Setb anode3
Reti
Show_Yekanhezar: Mov r2,#0
Clr anode3
Mov seven_segment,38H
Setb anode4
Reti
;----------------------------
Cseg at 180H
Number_Codes: db Zero,One,Two,Three,Four,Five,Six,Seven,Eight,Nine
End
همون طوری که می بینید نرم افزار این آزمایش نسبتاً طولانی هست و به نظر پیچیده میاد ولی نترسید . در واقع در نوشتن این برنامه که میتونه بعنوان زیربنای بسیاری از برنامه های بعدی باشه از روشهای زبانهای برنامه نویسی حرفه ای مثل C استفاده کردم تا قابلیت فهم برنامه و استفاده از زیر روالها در برنامه های دیگه فراهم بشه . میتونیم این برنامه را به قسمتهای مختلفی به شرح زیر تقسیم کنیم :
قسمت اول دستوراتی هست که تا قبل از دستور Org 0H قرار داره . این دستورات اصطلاحاً دایرکتیو نامیده میشه ، زیرا دستورات واقعی اسمبلی نیست و فقط به منظور افزایش خوانایی و قابلیت استفاده از زیر روالها در برنامه های مشابه به کار میره . مثلاً با دستور Zero equ 0C0H مقدار C0H به ثابت Zero ، با دستور Seven_Segment Data P0 نام مستعار Seven_Segment به پورت P0 و با دستور Anode1 bit P3.0 نام مستعار Anode1 به پایه ی P3.0 انتساب داده میشه . در واقع بعد از این دستورات هر جا اسمبلر به نامهای مستعار برخورد کنه ، مقادیر واقعی را جایگذاری میکنه .
قسم دوم ، تعیین برچسب پرش برنامه برای سرویس دهی به وقفه ی تایمر صفر هست که وظیفه ی مالتی پلکس کردن سون سگمنتها را بر عهده داره و در ادامه بیشتر در مورد آن توضیح خواهم داد . پس از تعیین برچسب زیر روال وقفه ی تایمر صفر ، برچسب پرش به آدرس قسمت اصلی برنامه یا همون Main هست . در این قسمت تعیین مد کاری تایمر صفر ، فعالسازی وقفه ی تایمر صفر و مقدار دهی اولیه به ثباتهای مورد استفاده از حافظه صورت میگیره و سرانجام تایمر صفر روشن میشه .
قسمت سوم همون حلقه ی اصلی برنامه هست که در این قسمت دائماً وضعیت منطقی پایه ی P1.0 برای دریافت یک لبه ی پاین رونده بررسی میشه و نرم افزار حذف چندین فشردگی پشت سر هم یا اصطلاحاً Debounce هم برای آن نوشته شده که با کمی بررسی میتونید به نحوه ی عملکرد آن پی ببرید . در صورت تشخیص یک پالس صحیح محتوای خانه ی 30H به داخل انباره(رجیستر A) کپی شده ، پس از جمع انباره با عدد 1 و تصحیح اعشاری آن ، محتوای انباره مجدداً به داخل خانه ی 30H کپی می شود . خانه ی 30H از حافظه محتوی اعداد یکان و دهگان شمارنده است که به فرم BCD بوده و به ترتیب در نیبلهای پایین و بالای آن قرار دارند . در صورتی که محتوای این خانه صفر شود که به منزله ی دریافت 100 پالس می باشد ، اعمالی که ذکر آنها در مورد خانه ی 30H گفته شد ، در مورد خانه ی 31H صورت می گیرد که در بردارنده ی صدگان و یکان هزار شمارنده است . پس از آن زیر برنامه ی Decode به منظور به هنگام کردن عددی که سون سگمنتها نشان می دهند فراخانی میشود که در ذیل توضیح داده میشود .
قسمت چهارم برنامه را به لحاظ اهمیتی که از نظر ساختار و نحوه ی عملکرد دارد میتوان زیر برنامه ی Decode دانست . نوشتن این زیر برنامه به روش زبانهای برنامه نویسی سطح بالا مانند C صورت گرفته است . این زیر برنامه یک ورودی و دو خروجی دارد که ورودی به خانه ی 32H ارسال شده و خروجیها در خانه های 33H و 34H از حافظه قرار داده می شوند . عملکرد این زیر برنامه به این صورت است که کد متناظر برای نمایش اعداد BCD روی سون سگمنت را برای نیبلهای بالا و پایین بایت ورودی (خانه ی 32H) با استفاده از دستور Movc a,@a+dptr از جدولی که در انتهای برنامه است استخراج کرده ، کد متناظر با نیبل پایین را در خانه ی 35H و کد متناظر با نیبل بالا را هم در خانه ی 36H قرار میدهد . قبل از فراخوانی این زیر برنامه بایستی بایت ورودی در خانه ی 32H قرارداده شود و پس از دستور فراخوانی (Acall Decode) ، محتوای خانه های 33H و 34H به خانه های مورد نظر برای نمایش روی سون سگمنت منتقل شود . همان طوری که می بینید این زیر برنامه پس از دریافت هر پالس و افزایش خانه های 30H و در صورت لزوم 31H که محتوی اعداد BCD هستند ، فراخوانی می شود تا اعداد نمایش داده شده روی سون سگمنت ها به هنگام شوند .
قسمت پنجم و در واقع آخرین قسمت برنامه زیر روال وقفه ی تایمر صفر هست که وظیفه ی مالتی پلکس کردن سون سگمنتها را بر عهده دارد و با برچسب Multiplex مشخص گردیده . این زیر روال با توجه به مقدار دهی اولیه ثباتهای تایمر یعنی TL0 و TH0 ، پس از هر 5 میلی ثانیه (در صورت استفاده از کریستال 12MHZ) ، یکبار اجرا می شود و یکی از سون سگمنتها را به مدت 5 میلی ثانیه روشن می کند . پس از هر سرریز تایمر و رخ دادن وقفه ، محتوای ثبات r2 یک واحد افزایش پیدا می کند و با توجه به مقدار آن که بین 1 تا 4 است ، ابتدا آند سون سگمنت قبلی صفر شده ، سپس محتوای خانه ی مورد نظر برای نمایش روی سون سگمنت مورد نظر بر روی پورت P0 که به پایه های a تا g سون سگمنتها متصل است قرار گرفته و در پایان پایه ی آند سون سگمنت مورد نظر ، یک می شود . در واقع در هر لحظه فقط یکی از سون سگمنتها و به مدت 5 میلی ثانی روشن است که چون اثر آن تا زمانی که دوباره روشن شود روی شبکیه باقی می ماند ، عمل مالتی پلکس توسط چشم تشخیص داده نمی شود و روشنی سون سگمنتها پیوسته به نظر می رسد . در صورت افزایش مقدار اولیه ثباتهای TL0 و TH0 یعنی تغییر عدد 5000- به 8000- که به ثابت Timer0_Preload انتساب داده شده ، میتونید عمل مالتی پلکس را ببینید .
امیدوارم از این آزمایش و توضیحاتی که در مورد سخت افزار و نرم افزار آن دادم استفاده ی لازم را برده باشید و این مطالب برای شما سودمند واقع شده باشه . با اعمال تغییرات کمی در سخت افزار و نرم افزار این آزمایش ، یک ساعت دیجیتالی درست کردم که دوستان علاقمند میتونند با ارسال یک Email به من به آدرس
stobaei@yahoo.com مبنی بر درخاست نقشه شماتیک و نرم افزار میکرو ، نقشه و نرم افزار را از طریق Email دریافت کنند .
تا آزمایش بعدی که اتصال صفحه کلید به میکروکنترلر هست همه ی شما علاقه مندان را به خدای بزرگ می سپارم و براتون آرزوی موفقیت دارم . یا علی .
آزمایش سوم : اتصال صفحه کلید به میکروکنترلر
با امید به اینکه آزمایشهای قبلی را با موفقیت انجام داده اید و با پوزش از عزیزانی که منتظر آپدیت شدن وبلاگ بوده اند به سراغ آزمایش سوم می رویم که اتصال صفحه کلید ماتریسی 16 تایی به میکروکنترلر می باشد و کاربردهای زیادی در اکثر پروژه های مبتنی بر مییکروکنترلر دارد . نقشه ی شماتیک سخت افزار را می توانید از اینجا دانلود کنید و نرم افزار را هم که در زیر مشاهده می کنید همان نرم افزاری است که در کتاب «میکروکنترلر 8051» نوشته ی محمد علی مزیدی برای اتصال صفحه کلید ماتریسی 16 تایی به میکروکنترلر پیشنهاد شده است . با این تفاوت که نرم افزار موجود در کتاب از 2 پورت استفاده می کند ولی نرم افزاری که در اینجا مشاهده می کنید برای استفاده از یک پورت بهینه شده است و برای نمایش اعداد مربوط به کلید های فشرده شده نیز از 4 عدد سون سگمنت که به روش مالتی پلکس بسته شده اند بهره می برد . توضیحات لازم در مورد نرم افزار صفحه کلید را در ذیل آن مشاهده می کنید و در مورد نرم افزار مالتی پلکس هم در آزمایش قبل به طور مفصل توضیح داده شده است .
Zero Equ 0C0H
One Equ 0F9H
Two Equ 0A4H
Three Equ 0B0H
Four Equ 99H
Five Equ 92H
six Equ 82H
Seven Equ 0F8H
Eight Equ 80H
Nine Equ 90H
_A Equ 88H
_B Equ 83H
_C Equ 0C6H
_D Equ 0A1H
_E Equ 86H
_F Equ 8EH
Timer0_Preload Equ -5000
seven_segment Data P0
KeypadPort Data P1
Yekan Data 35H
Dahgan Data 36H
Sadgan Data 37H
Yekan_Hezar Data 38H
Anode1 Bit P3.0
Anode2 Bit P3.1
Anode3 Bit P3.2
Anode4 Bit P3.3
;*******************************
Org 0H
Sjmp Main
;*******************************
Org 0BH
Ajmp Multiplex
;*******************************
Main: Mov Tmod,#01H
Mov IE,#82H
Mov r2,#0
Mov Yekan,#Zero
Mov Dahgan,#Zero
Mov Sadgan,#Zero
Mov Yekan_Hezar,#Zero
Mov Tl0,#low Timer0_Preload
Mov Th0,#high Timer0_Preload
Setb Tr0
Back1: Mov KeypadPort,#11110000B
Mov a,KeypadPort
Anl a,#11110000B
Cjne a,#11110000B,Back1
Back2: Acall Delay
Mov a,KeypadPort
Anl a,#11110000B
Cjne a,#11110000B,Over
Sjmp Back2
Over: Acall Delay
Mov a,KeypadPort
Anl a,#11110000B
Cjne a,#11110000B,Over1
Sjmp Back2
;* * * * * * * * * * * * * * * *
Over1: Mov KeypadPort,#11111110B
Mov a,KeypadPort
Anl a,#11110000B
Cjne a,#11110000B,Row_0
;* * * * * * * * * * * * * * * *
Mov KeypadPort,#11111101B
Mov a,KeypadPort
Anl a,#11110000B
Cjne a,#11110000B,Row_1
;* * * * * * * * * * * * * * * *
Mov KeypadPort,#11111011B
Mov a,KeypadPort
Anl a,#11110000B
Cjne a,#11110000B,Row_2
;* * * * * * * * * * * * * * * *
Mov KeypadPort,#11110111B
Mov a,KeypadPort
Anl a,#11110000B
Cjne a,#11110000B,Row_3
Ajmp Back2
;* * * * * * * * * * * * * * * *
Delay: Mov 40h,#50
Back3: Mov 41h,#100
Djnz 41h,$
Djnz 40h,Back3
Ret
;* * * * * * * * * * * * * * * *
Row_0: Mov Dptr,#Kcode0
Sjmp Find
Row_1: Mov Dptr,#Kcode1
Sjmp Find
Row_2: Mov Dptr,#Kcode2
Sjmp Find
Row_3: Mov Dptr,#Kcode3
;* * * * * * * * * * * * * * * *
Find: Rlc a
Jnc Match
Inc dptr
Sjmp Find
;* * * * * * * * * * * * * * * *
Match: Clr a
Movc a,@a+Dptr
Mov Dptr,#NumberCodes
Movc a,@a+Dptr
Mov Yekan_Hezar,Sadgan
Mov Sadgan,Dahgan
Mov Dahgan,Yekan
Mov Yekan,a
Ajmp Back1
;*******************************
Multiplex: Clr Tr0
Mov Tl0,#low Timer0_Preload
Mov Th0,#high Timer0_Preload
Setb Tr0
Inc r2
Cjne r2,#1,Show_Dahgan
Clr Anode4
Setb Anode1
Mov seven_segment,Yekan
Reti
Show_Dahgan: Cjne r2,#2,Show_Sahgan
Clr Anode1
Setb Anode2
Mov seven_segment,Dahgan
Reti
Show_Sahgan: Cjne r2,#3,Show_Yekanhezar
Clr Anode2
Setb Anode3
Mov seven_segment,Sadgan
Reti
Show_Yekanhezar: Mov r2,#0
Clr Anode3
Setb Anode4
Mov seven_segment,Yekan_Hezar
Reti
;*******************************
Cseg at 170H
Kcode0: Db 3,2,1,0
Kcode1: Db 7,6,5,4
Kcode2: Db 11,10,9,8
Kcode3: Db 15,14,13,12
;*******************************
Cseg at 180H
NumberCodes: Db Zero,One,Two,Three,Four,Five,Six,seven,Eight,Nine,_A,_B,_C,_ D,_E,_F
End
به طوری که در نقشه ی شماتیک مشاهده می کنید سطرها به 4 بیت کم ارزشتر و ستونها نیز به 4 بیت پرارزشتر پورت P1 متصل شده اند . نرم افزار مربوط به صفحه کلید را می توان به 4 قسمت تقسیم کرد که عملکرد هر قسمت به شرح ذیل است .
در ابتدا برای اطمینان از رهایی کلید قبلی به همه ی سطرها صفر اعمال شده و ستونها مرتباً خوانده و وارسی می گردند تا همه ی ستونها در سطح منطقی یک باشند . اگر همه ی ستونها در سطح یک تشخیص داده شوند برنامه قبل از رفتن به مرحله بعدی با فراخوانی زیر روال Delay مکث کرده و سپس در قسمت بعدی منتظر فشرده شدن کلید جدید می ماند .
در قسمت دوم نرم افزار ، برای یافتن کلید فشرده شده ستونها بوسیله یک حلقه نامتناهی مکرراً پویش می شوند تا یکی از آنها حاوی صفر شود . ذکر این نکته ضروری است که لچ های خروجی متصل به سطرها هنوز صفرهای خود را که در مرحله ی قبل تهیه شده اند دارند . نرم افزار پس از تشخیص فشردگی کلید ، با فراخوانی زیر روال Delay ، 20 میلی ثانیه برای حذف جهش ناشی از اتصال کلید صبر کرده و دوباره ستونها را پویش می کند . این کار دو مزیت دارد : 1- اطمینان از اینکه اولین تشخص فشردگی به دلیل پارازیت و نویز نبوده و 2- تأخیر 20 میلی ثانیه ای موجب می شود تا تا فشردن کلید مذکور بعنوان چندین فشردگی تعبیر نشود . اگر بعد از تأخیر 20 میلی ثانیه ، باز هم کلید فشرده شده تشخیص داده شد ، برنامه برای یافتن سطری که کلید فشرده شده در آن است به مرحله ی بعدی می رود و در غیر این صورت به حلقه ی تشخیص کلید فشرده شده ی واقعی بر می گردد .
در قسمت سوم ، نرم افزار به منظور تشخیص سطری که کلید فشرده شده در آن است ، هر بار فقط به یکی از سطرها صفر اعمال کرده و ستونها را بررسی می کند . اگر همه ی ستون ها در سطح بالا باشند بدین معناست که کلید فشرده شده متعلق به این سطر نیست . بنابراین به سطر بعدی صفر اعمال کرده و این عمل را تا یافتن سطر متعلق به کلید تکرار می کند . پس از مشخص شدن سطر متعلق به کلید فشرده شده ، ابتدا آدرس برچسبی که کدهای مربوط به آن سطر در آن تعریف شده اند به درون ثبات Dptr بار شده (مثلاً به صورت Mov Dptr,#Kcode0) و سپس برنامه برای یافتن کد مربوط به کلید فشرده شده به مرحله بعد می رود .
برای شناسایی کلید فشرده شده ، ثبات a که محتوی پورت متصل به صفحه کلید است ، از طریق پرچم نقلی به چپ چرخانده شده (با دستور Rlc a) و صفر بودن پرچم نقلی بررسی می شود . اگر پرچم نقلی صفر باشد ابتدا محتوای ثبات a صفر شده و سپس با دستور Movc a,@a+Dptr کد مربوط به کلید فشرده شده به درون ثبات a منتقل می شود . در صورتی که پرچم نقلی صفر نباشد ثبات Dptr برای اشاره به مکان بعدی در آدرس مورد نظر یک واحد افزایش می یابد .
در این مرحله ثبات a حاوی کد مربوط به کلید فشرده شده است که عددی بین 0 تا 15 می باشد . ولی برای نمایش این کد روی سون سگمنت می بایست به کد متناظر آن تبدیل شود که این کار نیز با استفاده از روش آدرس دهی اندیسی صورت می گیرد . البته می توان کدهای مربوط به اعداد و کاراکترها برای نمایش روی سون سگمنت را مستقیماً در محلهایی که با برچسب های Kcode0 تا 3 مشخص شده اند قرار داد تا دیگر به فرآیند تبدیل کد نیازی نباشد ولی در صورتی که بخواهیم با کدهای صفحه کلید عملیات محاسباتی انجام دهیم بایستی به همین روشی که در برنامه به کار رفته عمل کنیم .
اگر ترتیب اتصال سطرها و ستونها به پورتP1 مطابق نقشه ی شماتیک باشد ، با فشردن هر کلید عدد و یا کاراکتری که در نقشه ی شماتیک در زیر هر کلید است بر روی سون سگمنت نشان داده می شود . در صورتی که شما ترتیب دیگری را برای کلیدها انتظار دارید می توانید با دستکاری جدولی که در انتهای برنامه و با آدرسهای Kcode0 تا 3 تعریف شده به ترتیب مورد نظر برسید
منبع http://www.vis.ir